The SwapRes command changes the residue side-chain, trying to preserve the current rotamer. It does not do a search through rotamer space to find the best side-chain conformation.

A number of special residue names are supported to choose among different protonation states:

Hydrogens will be added to the new side-chain only if the object already contains hydrogens.

When swapping DNA/RNA bases, note that YASARA does not modify the backbone. So if you switch adenosine to uridine, YASARA will not add an oxygen to the C2* atom to account for the fact that Uridine appears only in RNA. Instead, you have to add the C2* hydroxyl group yourself by swapping the H2* hydrogen to oxygen .

Swapping single nucleotides that are not part of a DNA/RNA strand (ATP, GDP etc.) is also possible, see the example below.

The following macro gives an example for judging the quality of mutants created with SwapRes:

# Example for point mutation analysis.
# This is a qualitative approximation, true free energy calculations
# will be supported in YASARA Structure.
Clear
# Set the wild type residue (wtres) to mutate
proteinname='5tim'
wtres='Arg 207 Mol A'
# The mutants, wt must appear again as the first one
mutlist='Arg','Lys','Glu','Ala','Val','Asn','Tyr','Phe','Trp'
# Set the force field parameters
ForceField Amber99
Cutoff 7.86
Longrange Coulomb
Boundary Periodic
# Try all mutations
for i=1 to count mutlist
  mutres=mutlist(i)
  ShowMessage 'Analyzing mutation (wtres) -> (mutres)'
  # First calculate the solvation energy of the amino acid in the unfolded state,
  # so that we can detect the energetic cost of burying a polar/charged residue
  Clear
  BuildRes (mutres)
  AddCap ACE+NME
  Clean
  Cell Auto,Extension=10
  # Ignore the net charge
  Sim Init
  Charge 0
  unfoldedsolvenergy(i) = SolvEnergy
  Wait 30
  # Load the protein
  Clear
  LoadPDB (proteinname)
  Style Ribbon,BallStick
  DelRes Hetgroup
  Clean
  ZoomAtom CA Res (wtres)
  # Fix everything not close by
  FixAtom all with distance>6 from Res (wtres)
  # Make the mutation
  SwapRes (wtres),(mutres)
  # Energy minimize the environment of the residue
  Experiment Minimization
  Experiment On
  Wait ExpEnd
  # Save the scene for later manual inspection
  SaveSce (proteinname)_(wtres)_(mutres)
  # Calculate potential and solvation energy
  Charge 0
  potenergy(i) = Energy
  foldedsolvenergy(i) = SolvEnergy
# Print the results
Console Off
print 'Results of the simple mutation analysis, negative values are better than the wildtype:'
print '[This is a qualitative estimate, quantitative free energies will be supported in YASARA Structure]'
for i=1 to count mutlist
  print 'Mutation (wtres) -> (mutlist(i)):'
  print '  Potential energy = (0.00+potenergy(i)), Solvation energy = (0.00+foldedsolvenergy(i)) [folded] and (0.00+unfoldedsolvenergy(i)) [unfolded] (EnergyUnit)'
  print '  Total energy difference to wildtype = (0.00+(potenergy(i)+foldedsolvenergy(i)-unfoldedsolvenergy(i))-(potenergy(1)+foldedsolvenergy(1)-unfoldedsolvenergy(1))) (EnergyUnit)'
Console On

SwapRes Lys 15,Ile

Mutate lysine 15 to isoleucine.

SwapRes Ala,Trp

Mutate all alanines to tryptophanes.

SwapRes A 6,T

Mutate adenosine 5 to thymine.

SwapRes GDP,A

Mutate all GDP residues to ADP.

SwapRes Obj 5,Ala

Make object 5 an alanine-only structure.

# EXAMPLE SwapRes
Clear
LoadPDB 1crn
Style Stick
SwapRes All,Trp