The ShowSecStr command shows the secondary structure of the selected residues using a tube, ribbon or cartoon, as specified by the Style parameter.

The default color of the secondary structure elements is chosen if the CA atom has the default element color and not all backbone atoms in the residue share the same color. Otherwise the secondary structure elements inherit the CA color.

YASARA uses its own secondary structure assignment routines to determine the location of the following four secondary structure types: alpha helix (by default colored blue), beta sheet (red), turn (green) and coil (cyan). If you feel the need to change this assignment (i.e. force YASARA to display a helix in a certain range), this indicates a problem. Either YASARA did not assign the secondary structure correctly (then please report it as a bug and send us the PDB file) or you want to show a secondary structure that is not present. In such a case there are two options:

• Change the secondary structure assignment with the SecStr command.

• Change the atom coordinates so that YASARA automatically assigns the correct secondary structure. This is easily done using the AddSpring command in YASARA Dynamics+:

LoadPDB MyStructure

# List your helical regions, e.g. from residues 68-75 and 93-98 etc.
helix=68,75, 93,98, 118,124, 143,150, 169,176, 194,199, 217,224

# Prepare to minimize
Clean
ForceField Nova
Cutoff 10.48
Cell Auto
# Energy minimize
TempCtrl SteepDes
Sim On
# Add helical distance restraints
for i=1 to count helix step 2
  first=helix(i)
  last=helix(i+1)
  for j=first to last-4
    # Add springs, but only to protein, not to waters
    AddSpring O Protein Res (j),H Protein Res (j+4),2.0
Wait SpeedMax<3000
TempCtrl Anneal
Wait 500
Sim Off

To save time, secondary structure is not updated at every step of a simulation, look here for a solution.

Tubes and ribbons bridge gaps in the chain, provided that the following points apply:

• The peptide bond is present.
• Residues have been joined, there is no split point in between.
• The residue before the gap has exactly one backbone oxygen named 'O'.

Unusual amino acids in the protein are normally handled like any standard amino acid, secondary structure is assigned and ribbons pass through the Calpha atom if the following conditions are met:

• The residue contains atoms named N, CA, C and O.
• The residue name is in the PDB's hetgroup dictionary OR the bonds N-CA, CA-C and C=O are present.
• The Calpha atom is connected through bonds with the preceding or the following Calpha.

The second condition is always fulfilled for amino acids with unusual side-chains, but can be problematic for amino acids with unusual backbone atoms. In this case, rename the residue to any non-standard amino acid in the PDB's hetgroup dictionary (e.g. 'UNK'), then the connectivities are not checked.

Cyclic peptides may pose problems if the cyclic peptide bond is in a beta sheet or alpha helix, since the secondary structure assignment algorithm does currently not wrap around at the end and will thus miss part of the secondary structure element. The solution is to move the cyclic peptide bond into a loop or turn, for example with the following macro:

Clear
LoadPDB cyclic_peptide
# Define a residue in a turn, Proline 4 in this example
turn='Pro 4'
# Add TER entries before all residues
SplitRes all
# Split at TERs, making each residue a separate object
SplitAll
# Get the object which now contains the turn residue
first = ListObj Res (turn)
# Join the objects in the new order
JoinObj not 1-(first),(first)
JoinObj 1-(first-1),(first)
# Remove the TER entries again
JoinRes all
# Add the peptide bonds that got lost during the split
LinkAll
# Make the new object number 1
SwapObj 1,(first)

ShowSecStrRes 20-30

Show a ribbon through residues 20-30 and leave the individial atoms untouched.

ShowSecStrObj 1crn,Style=Tube,HideAtoms=Yes

Show a tube through object 1crn and hide the individual atoms.

# EXAMPLE ShowSecStr Tube
Clear
LoadPDB 1crn
OriObj 1crn,50,-35,0
PosObj 1crn,Z=20
HideAtom Sidechain
Stick
ShowSecStr Tube

# EXAMPLE ShowSecStr Ribbon
Clear
LoadPDB 1crn
OriObj 1crn,50,-35,0
PosObj 1crn,Z=20
Stick
ShowSecStr Ribbon

# EXAMPLE ShowSecStr Cartoon
Clear
LoadPDB 1crn
OriObj 1crn,50,-35,0
PosObj 1crn,Z=20
Stick
BallStickAtom Sidechain
ShowSecStr Cartoon